// Picotest M3500A 6.5 Digit Digital Multimeter.
instrument usbtmc 164E 0DAD

// File name for the measurements.
#filename set "E:\Measurements - /F /O - Skript 1.csv"
#separator set , // ; Use semi-colon for a German Excel.

// Reset the multimeter.
function scpi write *RST

// Measuring volt DC.
function scpi write :SENSe:FUNCtion "VOLTage:DC"
// Set ADC (Auto Zero).
function scpi write :SENSe:ZERO:AUTO ON // OFF|ONCE|ON
// Set digital filter.
function scpi write :SENSe:AVERage:TCONtrol MOVing // MOVing|REPeat
function scpi write :SENSe:AVERage:COUNt 10 // <value>|MINimum|MAXimum
function scpi write :SENSe:AVERage:STATe ON // ON|OFF
// Resolution setting,
//function scpi write :SENSe:VOLTage:DC:RESolution MIN // <value>|MINimum|MAXimum
// or Rate (integration time).
function scpi write :SENSe:VOLTage:DC:NPLCycles 10 // 0.02|0.1|1|10|MINimum|MAXimum
// DC input resistance.
function scpi write :INPut:IMPedance:AUTO OFF // OFF|ON - Off is 10 MOhm for all ranges, On is 10 GOhm for 100 mV,  1V and 10 V.
// Range.
function scpi write :SENSe:VOLTage:DC:RANGe 10 // <value>|MINimum|MAXimum

// Trigger.
function scpi write :TRIGger:SOURce IMMediate
function scpi write :TRIGger:DELay:AUTO ON // OFF|ON

// Prepare file.
string measurement
measurement set "time"
measurement add #separator
measurement add "number"
measurement add #separator
measurement add "volt"
measurement function save eol #filename

// Make measurements.
#number set 10 // Number of measurements.
float volt
integer count

label loop
function wait abs 2000 // Milliseconds.
volt function scpi read :READ?
count add 1
measurement set $time2
measurement add #separator
measurement add count
measurement add #separator
measurement add volt

// Save the measurement.
measurement function save add eol #filename

count equal #number
false goto loop

// Place the multimeter in the local mode.
function scpi write :SYSTem:LOCal
